DEVELOPMENT ENVIRONMENT

~liljamo/nix-arta

ref: b4b10c57262b557f623247447f10d5366d136765 nix-arta/roles/prometheus.nix -rw-r--r-- 1.7 KiB
b4b10c57 — Jonni Liljamo feat: rest of lxc common, working dns configuration 3 months ago 
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

{
  lib,
  config,
  ...
}: let
  cfg = config.roles.prometheus;
in {
  options.roles.prometheus = {
    exporters = lib.mkOption {
      type = lib.types.submodule {
        options = {
          openFirewall = lib.mkOption {
            type = lib.types.bool;
            default = false;
            description = "Wheter to open firewall ports for enabled exporters";
          };
          node = lib.mkOption {
            type = lib.types.submodule {
              options = {
                enable = lib.mkEnableOption "node exporter";
                port = lib.mkOption {
                  type = lib.types.port;
                  default = 9100;
                };
                extraFlags = lib.mkOption {
                  type = lib.types.listOf lib.types.str;
                  default = [];
                };
              };
            };
          };
          systemd = lib.mkOption {
            type = lib.types.submodule {
              options = {
                enable = lib.mkEnableOption "systemd exporter";
                port = lib.mkOption {
                  type = lib.types.port;
                  default = 9558;
                };
              };
            };
          };
        };
      };
    };
  };

  config = {
    networking.firewall.allowedTCPPorts = lib.mkIf cfg.exporters.openFirewall [
      cfg.exporters.node.port
      cfg.exporters.systemd.port
    ];

    services.prometheus.exporters = {
      node = lib.mkIf cfg.exporters.node.enable {
        enable = true;
        port = cfg.exporters.node.port;
        extraFlags = cfg.exporters.node.extraFlags;
      };
      systemd = lib.mkIf cfg.exporters.systemd.enable {
        enable = true;
        port = cfg.exporters.systemd.port;
      };
    };
  };
}