{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };

    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    templ = {
      url = "github:a-h/templ?ref=tags/v0.2.793";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {
    self,
    nixpkgs,
    flake-parts,
    pre-commit-hooks,
    templ,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux"];
      perSystem = {
        config,
        lib,
        pkgs,
        system,
        ...
      }: let
        libs = [];
      in {
        checks.pre-commit-check = pre-commit-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            # Nix formatting
            alejandra.enable = true;

            # Go formatting, linting, static checking
            gofmt.enable = true;
            govet.enable = true;
            revive.enable = true;

            # Spell checking
            typos = {
              enable = true;
              excludes = ["static/htmx.min.js"];
            };
          };
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs;
            [
              just

              go
              gopls

              air

              tailwindcss
              tailwindcss-language-server
            ]
            ++ libs
            ++ [
              templ.packages.${system}.default
              self.checks.${system}.pre-commit-check.enabledPackages
            ];
          LD_LIBRARY_PATH = lib.makeLibraryPath libs;
          shellHook = ''
            ${self.checks.${system}.pre-commit-check.shellHook}
          '';
        };
      };
    };
}